Home > Language Reference > Classes

UserControl Class

  + Object
    + Display
      + UIComponent
        + Control
          + UserControl

Description

The UserControl class implements functionalities common to all user controls. This class is not instantiable, cloneable or directly derivable. To create a user control, you should create a new module in your project by selecting the "Project > Add user control" menu then review its different design time properties. The module thus created declares a new class whose name is given by the Name property and the parent class is UserControl.

You can then place as many instances of this new control wherever you want on forms, just like you can do with any other built-in control, by selecting the corresponding control icon in the Toolbox Window of the development environment.

By default, a user control has no defined behaviour and aspect: it does not appear on screen and does not respond to taps by the user. So that your control behaves correctly, you should implement event handlers for the different events that can occur.

The principal event is Paint which is raised by the system whenever the control needs to be redrawn. Except in special cases, all control drawing procedures must be located in this event handler otherwise your control may not appear properly on screen.

Inherited from the UIComponent class, the PenDown, PenMove and PenUp events are raised respectively when the user presses down, moves and release the stylus on the control.

Finally, the Load and Unload events are raised when loading and unloading the form that contains the control, and can be used to initialize the values of member variables, and load or free up resources.

The following example shows how to create a user control that displays the available memory space in the heap, either as a gauge or a number. The user can switch from one display mode to the other by tapping the control.

Private bText As Boolean
Private lMemSize As Long
Private lMemFree As Long

Private Sub UserControl_Load()
  bText=False
  lMemSize=MemInfo(hbMemHeapSize)
  lMemFree=MemInfo(hbMemHeapFree)
End Sub

Private Sub UserControl_Paint()
  Dim k as Long, s as String

  If bText Then
    ForeColor=UIColor(hbUIObjectFrame)
    BackColor=UIColor(hbUIObjectFill)
    Rectangle 0, 0, Width-1, Height-1, hbRectBorderSolid+hbRectFillSolid

    DrawFont = hbFontStandard
    TextColor=UIColor(hbUIObjectForeground)
    s = Format(lMemFree/1024.0,"#.00") & " Ko / " & Format(lMemSize/1024.0,"#.00") & " Ko"
    Textout Width/2, Height/2,s,hbTextAlignCenter+hbTextAlignVCenter
  Else
    ForeColor=UIColor(hbUIObjectFrame)
    BackColor=UIColor(hbUIObjectFill)
    Rectangle 0, 0, Width-1, Height-1, hbRectBorderSolid+hbRectFillSolid

    k = (Width-3)*(lMemSize-lMemFree)/lMemSize
    If k<>0 Then
      BackColor=UIColor(hbUIObjectSelectedFill)
      Rectangle 1, 1, k+1, Height-2, hbRectBorderNone+hbRectFillSolid
    End If
  End If
End Sub

Private Sub UserControl_PenUp(ByVal x As Integer, ByVal y As Integer)
  bText=Not bText
  Repaint
End Sub

Members

System requirements